***********************************************************************
***********           PANJIT International Inc.             ***********
***********************************************************************
*Mar 31, 2018                                                         *
*                                                                     *
*This SPICE Model describes the characteristics of a typical device   *
*and does not respresent the specification. Designer should refer to  *
*the same type name data sheet for specification limits.              *
***********************************************************************
*$
.SUBCKT  PJA3460-AU  D  G  S
rg     G    1t    1
m1     2     1    3    3    dmos    L=1u   W=1u
.model dmos nmos ( 
+vto = 1.9		
+kp = 7.6		
+tnom = 25
+level = 3		gamma = 1.45	;kappa = 0.2
+rd = 4e-3		)   
cgs	1t	 3	1.24n	ic = 0
rd	 D	 4	4e-3	tc=2e-3
dds	 3	 4	dds
.model dds d (
+bv = 66		ibv = 0.25e-6		tbv1 = 0.77e-3
+m = 0.1971		cjo=393p		vj=0.06487
+is = 1.7e-11		n = 1.167		rs = 27e-3		trs1 = 3e-3)
e1	1 3 table { v(1t, S) } 
+ ((0   , 0   )
+  (1.00, 1.00)
+  (1.50, 1.50)
+  (2.50, 2.30)
+  (3.50, 4.10)
+  (3.75, 4.30)
+  (4.00, 4.36)
+  (4.50, 4.45)
+  (20.0, 4.90)) 
dbody   3   D    dbody
*gds D S value = {1e-2*(temp-25)*limit((v(G,S)-2),0,1.5)*limit(v(D,S),0,1)}
.model   dbody    d(
+is = 1.7e-11		n = 1.167		rs = 27e-3		trs1 = 3e-3	
+tt = 100n		vj = 0.8		eg = 1.146 )
ra      4    2    5e-3  tc=5e-2
rs      3    5    2e-3
ls      5    S   0.0001n
m2      1t    8    6    6   inter
e2      8    6    4    1t   2
.model	inter	nmos(vto=0	kp=10	level=1) 
cgdmax  7    4    431p ic=0
rcgd    7    4    10meg
dgd     6    4    dgd
rdgd    4    6    10meg
.model     dgd    d(m=0.3   cjo=68p   vj=0.4)
m3      7    9    1t    1t   inter
e3      9    1t    4    1t   -2
.ends
*$
